From 91107f553a477c6eb49588bb04c2c71b7bf83e08 Mon Sep 17 00:00:00 2001
From: Scott Anderson <ascent12@hotmail.com>
Date: Sun, 24 Sep 2017 14:52:09 +1300
Subject: [PATCH] Add Archlinux PKGBUILD script

---
 dist/archlinux/PKGBUILD | 48 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dist/archlinux/PKGBUILD

diff --git a/dist/archlinux/PKGBUILD b/dist/archlinux/PKGBUILD
new file mode 100644
index 00000000..a65fc7ff
--- /dev/null
+++ b/dist/archlinux/PKGBUILD
@@ -0,0 +1,48 @@
+pkgname=wlroots
+pkgver=r600.d89272d
+pkgrel=1
+license=('MIT')
+pkgdesc='Wayland compositor library'
+makedepends=("meson")
+depends=(
+	"wayland"
+	"wayland-protocols"
+	"mesa"
+	"libdrm"
+	"libinput"
+	"libxkbcommon"
+	"libsystemd"
+	"pixman"
+	"libxcb"
+)
+arch=("x86_64")
+url="https://github.com/SirCmpwn/wlroots"
+source=("${pkgname}::git+https://github.com/SirCmpwn/wlroots.git")
+sha1sums=('SKIP')
+provides=('wlroots')
+conflicts=('wlroots')
+
+pkgver() {
+	cd "${srcdir}/${pkgname}"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	cd "${srcdir}/${pkgname}"
+
+	meson build \
+		--prefix=/usr \
+		-Dbuildtype=debugoptimized \
+		-Db_lto=True \
+		-Denable-systemd=True \
+		-Denable-elogind=False \
+		-Denable-libcap=False
+
+	ninja -C build
+}
+
+package() {
+	cd "${srcdir}/${pkgname}"
+
+	DESTDIR="${pkgdir}" ninja -C build install
+}