From 5087c3d64d9357c4fb49af36b6c1c105a3fab363 Mon Sep 17 00:00:00 2001
From: ppenguin <hieronymusv@gmail.com>
Date: Wed, 27 Nov 2024 20:21:57 +0100
Subject: [PATCH] languages/HCL: init (#359)

* add language HCL

Terraform doesn't register hcl and doesn't offer good DX if manually set
for editing e.g. nomad HCL files.

Incl. reformat with alejandra

* cleanup, add formatter

* requested improvements

forgotten save

typo (lsp <-> format)

* changelog entry

consolidate changelog entry

---------

Co-authored-by: raf <raf@notashelf.dev>
---
 docs/release-notes/rl-0.7.md          |   1 +
 modules/plugins/languages/default.nix |   1 +
 modules/plugins/languages/hcl.nix     | 117 ++++++++++++++++++++++++++
 3 files changed, 119 insertions(+)
 create mode 100644 modules/plugins/languages/hcl.nix

diff --git a/docs/release-notes/rl-0.7.md b/docs/release-notes/rl-0.7.md
index 876f1ab2..dccece29 100644
--- a/docs/release-notes/rl-0.7.md
+++ b/docs/release-notes/rl-0.7.md
@@ -297,6 +297,7 @@ To migrate to `nixfmt`, simply change `vim.languages.nix.format.type` to
 - Telescope:
   - Fixed `project-nvim` command and keybinding
   - Added default ikeybind/command for `Telescope resume` (`<leader>fr`)
+- Add `hcl` lsp/formatter (not the same as `terraform`, which is not useful for e.g. `nomad` config files).
 
 [Soliprem](https://github.com/Soliprem):
 
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index b3b019bc..d074cb8c 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -9,6 +9,7 @@ in {
     ./css.nix
     ./elixir.nix
     ./go.nix
+    ./hcl.nix
     ./kotlin.nix
     ./html.nix
     ./java.nix
diff --git a/modules/plugins/languages/hcl.nix b/modules/plugins/languages/hcl.nix
new file mode 100644
index 00000000..e340e74d
--- /dev/null
+++ b/modules/plugins/languages/hcl.nix
@@ -0,0 +1,117 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) package bool enum;
+  inherit (lib.nvim.types) mkGrammarOption;
+
+  cfg = config.vim.languages.hcl;
+
+  defaultServer = "terraform-ls";
+  servers = {
+    terraform-ls = {
+      package = pkgs.terraform-ls;
+      lspConfig = ''
+        lspconfig.terraformls.setup {
+          capabilities = capabilities,
+          on_attach=default_on_attach,
+          cmd = {"${lib.getExe cfg.lsp.package}", "serve"},
+        }
+      '';
+    };
+  };
+
+  defaultFormat = "hclfmt";
+  formats = {
+    hclfmt = {
+      package = pkgs.hclfmt;
+      nullConfig = ''
+        table.insert(
+          ls_sources,
+          null_ls.builtins.formatting.hclfmt.with({
+            command = "${lib.getExe cfg.format.package}",
+          })
+        )
+      '';
+    };
+  };
+in {
+  options.vim.languages.hcl = {
+    enable = mkEnableOption "HCL support";
+
+    treesitter = {
+      enable = mkEnableOption "HCL treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "hcl";
+    };
+
+    lsp = {
+      enable = mkEnableOption "HCL LSP support (terraform-ls)" // {default = config.vim.languages.enableLSP;};
+      # TODO: (maybe, is it better?) it would be cooler to use vscode-extensions.hashicorp.hcl probably, shouldn't be too hard
+      package = mkOption {
+        type = package;
+        default = servers.${defaultServer}.package;
+        description = "HCL language server package (terraform-ls)";
+      };
+    };
+
+    format = {
+      enable = mkOption {
+        type = bool;
+        default = config.vim.languages.enableFormat;
+        description = "Enable HCL formatting";
+      };
+      type = mkOption {
+        type = enum (attrNames formats);
+        default = defaultFormat;
+        description = "HCL formatter to use";
+      };
+      package = mkOption {
+        type = package;
+        default = formats.${cfg.format.type}.package;
+        description = "HCL formatter package";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    {
+      # hcl style official: https://developer.hashicorp.com/terraform/language/style#code-formatting
+      vim.pluginRC.hcl = ''
+        vim.api.nvim_create_autocmd("FileType", {
+          pattern = "hcl",
+          callback = function(opts)
+            local bo = vim.bo[opts.buf]
+            bo.tabstop = 2
+            bo.shiftwidth = 2
+            bo.softtabstop = 2
+          end
+        })
+
+        local ft = require('Comment.ft')
+        ft
+          .set('hcl', '#%s')
+      '';
+    }
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources = lib.optionalAttrs (! config.vim.languages.terraform.lsp.enable) {
+        terraform-ls = servers.${cfg.lsp.server}.lspConfig;
+      };
+    })
+
+    (mkIf cfg.format.enable {
+      vim.lsp.null-ls.enable = true;
+      vim.lsp.null-ls.sources.hcl-format = formats.${cfg.format.type}.nullConfig;
+    })
+  ]);
+}