From db810bbf9f2d38ec92dc415aab7ac09fdca3913e Mon Sep 17 00:00:00 2001
From: jacekpoz <jacekpoz@proton.me>
Date: Wed, 15 May 2024 19:37:27 +0200
Subject: [PATCH] languages/ocaml: init

---
 docs/release-notes/rl-0.7.md          |  4 ++
 modules/plugins/languages/default.nix |  1 +
 modules/plugins/languages/ocaml.nix   | 56 +++++++++++++++++++++++++++
 3 files changed, 61 insertions(+)
 create mode 100644 modules/plugins/languages/ocaml.nix

diff --git a/docs/release-notes/rl-0.7.md b/docs/release-notes/rl-0.7.md
index 8f3ffd2..0a304dd 100644
--- a/docs/release-notes/rl-0.7.md
+++ b/docs/release-notes/rl-0.7.md
@@ -38,3 +38,7 @@ Release notes for release 0.7
 
 - Cleaned up Lualine module to reduce theme dependency on Catppuccin, and fixed
   blending issues in component separators.
+
+[jacekpoz](https://github.com/jacekpoz):
+
+- Added [ocaml-lsp](https://github.com/ocaml/ocaml-lsp) support.
diff --git a/modules/plugins/languages/default.nix b/modules/plugins/languages/default.nix
index 279d46b..e86a521 100644
--- a/modules/plugins/languages/default.nix
+++ b/modules/plugins/languages/default.nix
@@ -14,6 +14,7 @@ in {
     ./markdown.nix
     ./nim.nix
     ./nix.nix
+    ./ocaml.nix
     ./php.nix
     ./python.nix
     ./rust.nix
diff --git a/modules/plugins/languages/ocaml.nix b/modules/plugins/languages/ocaml.nix
new file mode 100644
index 0000000..c6ff5a5
--- /dev/null
+++ b/modules/plugins/languages/ocaml.nix
@@ -0,0 +1,56 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.meta) getExe;
+  inherit (lib.lists) isList;
+  inherit (lib.types) either listOf package str;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.lua) expToLua;
+
+  cfg = config.vim.languages.ocaml;
+in {
+  options.vim.languages.ocaml = {
+    enable = mkEnableOption "OCaml language support";
+
+    treesitter = {
+      enable = mkEnableOption "OCaml treesitter" // {default = config.vim.languages.enableTreesitter;};
+      package = mkGrammarOption pkgs "ocaml";
+    };
+
+    lsp = {
+      enable = mkEnableOption "OCaml LSP support (ocaml-lsp)" // {default = config.vim.languages.enableLSP;};
+      package = mkOption {
+        description = "ocaml language server package, or the command to run as a list of strings";
+        type = either package (listOf str);
+        default = pkgs.ocamlPackages.ocaml-lsp;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.lsp.enable {
+      vim.lsp.lspconfig.enable = true;
+      vim.lsp.lspconfig.sources.ocaml-lsp = ''
+        lspconfig.ocamllsp.setup {
+          capabilities = capabilities,
+          on_attach = default_on_attach,
+            cmd = ${
+            if isList cfg.lsp.package
+            then expToLua cfg.lsp.package
+            else ''{"${getExe cfg.lsp.package}"}''
+          };
+        }
+      '';
+    })
+
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+  ]);
+}