nixos: use attrset for long function args

the bulk of the build step is moved to modules/wrapper/build

flake.nix

@@ -31,7 +31,10 @@
         };
 
         homeManagerModules = {
-          nvf = import ./flake/modules/home-manager.nix self.packages lib;
+          nvf = import ./flake/modules/home-manager.nix {
+            inherit lib inputs;
+            inherit (self) packages;
+          };
           default = self.homeManagerModules.nvf;
           neovim-flake =
             lib.warn ''
@@ -42,7 +45,10 @@
         };
 
         nixosModules = {
-          nvf = import ./flake/modules/nixos.nix self.packages lib;
+          nvf = import ./flake/modules/nixos.nix {
+            inherit lib inputs;
+            inherit (self) packages;
+          };
           default = self.nixosModules.nvf;
           neovim-flake =
             lib.warn ''

flake/modules/home-manager.nix

@@ -1,5 +1,9 @@
 # Home Manager module
-packages: lib: {
+{
+  packages,
+  lib,
+  inputs,
+}: {
   config,
   pkgs,
   ...
@@ -8,15 +12,17 @@ packages: lib: {
   inherit (lib.modules) mkIf mkAliasOptionModule;
   inherit (lib.lists) optional;
   inherit (lib.options) mkOption mkEnableOption literalExpression;
-  inherit (lib.types) attrsOf anything bool;
+  inherit (lib.types) anything bool submoduleWith;
-  inherit (lib.nvim) neovimConfiguration;
-  inherit (lib.nvim.types) anythingConcatLists;
 
   cfg = config.programs.nvf;
 
-  neovimConfigured = neovimConfiguration {
+  nvfModule = submoduleWith {
-    inherit pkgs;
+    description = "Nvf module";
-    modules = [cfg.settings];
+    class = "nvf";
+    specialArgs = {
+      inherit pkgs lib inputs;
+    };
+    modules = import ../../modules/modules.nix {inherit pkgs lib;};
   };
 in {
   imports = [
@@ -55,7 +61,7 @@ in {
     };
 
     settings = mkOption {
-      type = attrsOf anythingConcatLists;
+      type = nvfModule;
       default = {};
       description = "Attribute set of nvf preferences.";
       example = literalExpression ''
@@ -78,7 +84,7 @@ in {
   };
 
   config = mkIf cfg.enable {
-    programs.nvf.finalPackage = neovimConfigured.neovim;
+    programs.nvf.finalPackage = config.programs.nvf.settings.vim.build.finalPackage;
 
     home = {
       sessionVariables = mkIf cfg.defaultEditor {EDITOR = "nvim";};

flake/modules/nixos.nix

@@ -1,5 +1,9 @@
 # NixOS module
-packages: lib: {
+{
+  packages,
+  lib,
+  inputs,
+}: {
   config,
   pkgs,
   ...
@@ -8,15 +12,17 @@ packages: lib: {
   inherit (lib.modules) mkIf mkOverride mkAliasOptionModule;
   inherit (lib.lists) optional;
   inherit (lib.options) mkOption mkEnableOption literalExpression;
-  inherit (lib.types) attrsOf anything bool;
+  inherit (lib.types) anything bool submoduleWith;
-  inherit (lib.nvim) neovimConfiguration;
-  inherit (lib.nvim.types) anythingConcatLists;
 
   cfg = config.programs.nvf;
 
-  neovimConfigured = neovimConfiguration {
+  nvfModule = submoduleWith {
-    inherit pkgs;
+    description = "Nvf module";
-    modules = [cfg.settings];
+    class = "nvf";
+    specialArgs = {
+      inherit pkgs lib inputs;
+    };
+    modules = import ../../modules/modules.nix {inherit pkgs lib;};
   };
 in {
   imports = [
@@ -55,7 +61,7 @@ in {
     };
 
     settings = mkOption {
-      type = attrsOf anythingConcatLists;
+      type = nvfModule;
       default = {};
       description = "Attribute set of nvf preferences.";
       example = literalExpression ''
@@ -78,7 +84,7 @@ in {
   };
 
   config = mkIf cfg.enable {
-    programs.nvf.finalPackage = neovimConfigured.neovim;
+    programs.nvf.finalPackage = config.programs.nvf.settings.vim.build.finalPackage;
 
     environment = {
       variables.EDITOR = mkIf cfg.defaultEditor (mkOverride 900 "nvim");

lib/types/custom.nix

@@ -1,57 +1,9 @@
 {lib}: let
-  inherit (lib.options) showOption showFiles getFiles mergeOneOption mergeEqualOption;
+  inherit (lib.options) mergeEqualOption;
-  inherit (lib.strings) isString isStringLike;
+  inherit (lib.strings) isString;
-  inherit (lib.types) anything attrsOf listOf mkOptionType;
+  inherit (lib.types) listOf mkOptionType;
-  inherit (lib.nvim.types) anythingConcatLists;
+  inherit (builtins) stringLength match;
-  inherit (builtins) typeOf isAttrs any head concatLists stringLength match;
 in {
-  # HACK: Does this break anything in our case?
-  # A modified version of the nixpkgs anything type that concatenates lists
-  # This isn't the default because the order in which the lists are concatenated depends on the order in which the modules are imported,
-  # which makes it non-deterministic
-  anythingConcatLists =
-    anything
-    // {
-      merge = loc: defs: let
-        getType = value:
-          if isAttrs value && isStringLike value
-          then "stringCoercibleSet"
-          else typeOf value;
-
-        # Throw an error if not all defs have the same type
-        checkType = getType (head defs).value;
-        commonType =
-          if any (def: getType def.value != checkType) defs
-          then throw "The option `${showOption loc}' has conflicting option types in ${showFiles (getFiles defs)}"
-          else checkType;
-
-        mergeFunctions = {
-          # Recursively merge attribute sets
-          set = (attrsOf anythingConcatLists).merge;
-
-          # Overridden behavior for lists, that concatenates lists
-          list = _: defs: concatLists (map (e: e.value) defs);
-
-          # This means it's a package, only accept a single definition
-          stringCoercibleSet = mergeOneOption;
-
-          # This works by passing the argument to the functions,
-          # and merging their returns values instead
-          lambda = loc: defs: arg:
-            anythingConcatLists.merge
-            (loc ++ ["<function body>"])
-            (map (def: {
-                inherit (def) file;
-                value = def.value arg;
-              })
-              defs);
-        };
-      in
-        # Merge the defs with the correct function from above, if available
-        # otherwise only allow equal values
-        (mergeFunctions.${commonType} or mergeEqualOption) loc defs;
-    };
-
   mergelessListOf = elemType: let
     super = listOf elemType;
   in

lib/types/default.nix

@@ -11,5 +11,5 @@ in {
   inherit (typesDag) dagOf;
   inherit (typesPlugin) pluginsOpt extraPluginType mkPluginSetupOption luaInline pluginType borderType;
   inherit (typesLanguage) diagnostics mkGrammarOption;
-  inherit (customTypes) anythingConcatLists char hexColor mergelessListOf;
+  inherit (customTypes) char hexColor mergelessListOf;
 }

modules/default.nix

@@ -9,9 +9,8 @@
   extraModules ? [],
   configuration ? {},
 }: let
-  inherit (pkgs) vimPlugins;
+  inherit (lib.strings) toString;
-  inherit (lib.strings) isString toString;
+  inherit (lib.lists) concatLists;
-  inherit (lib.lists) filter map concatLists;
 
   # import modules.nix with `check`, `pkgs` and `lib` as arguments
   # check can be disabled while calling this file is called
@@ -21,7 +20,12 @@
   # evaluate the extended library with the modules
   # optionally with any additional modules passed by the user
   module = lib.evalModules {
-    specialArgs = extraSpecialArgs // {modulesPath = toString ./.;};
+    specialArgs =
+      extraSpecialArgs
+      // {
+        inherit inputs;
+        modulesPath = toString ./.;
+      };
     modules = concatLists [
       nvimModules
       modules
@@ -36,102 +40,11 @@
         extraModules))
     ];
   };
-
-  # alias to the internal configuration
-  vimOptions = module.config.vim;
-
-  noBuildPlug = {pname, ...} @ attrs: let
-    src = inputs."plugin-${attrs.pname}";
-  in
-    {
-      version = src.shortRev or src.shortDirtyRev or "dirty";
-      outPath = src;
-      passthru.vimPlugin = false;
-    }
-    // attrs;
-
-  # build a vim plugin with the given name and arguments
-  # if the plugin is nvim-treesitter, warn the user to use buildTreesitterPlug
-  # instead
-  buildPlug = attrs: let
-    src = inputs."plugin-${attrs.pname}";
-  in
-    pkgs.vimUtils.buildVimPlugin (
-      {
-        version = src.shortRev or src.shortDirtyRev or "dirty";
-        inherit src;
-      }
-      // attrs
-    );
-
-  buildTreesitterPlug = grammars: vimPlugins.nvim-treesitter.withPlugins (_: grammars);
-
-  pluginBuilders = {
-    nvim-treesitter = buildTreesitterPlug vimOptions.treesitter.grammars;
-    flutter-tools-patched = buildPlug {
-      pname = "flutter-tools";
-      patches = [../patches/flutter-tools.patch];
-    };
-  };
-
-  buildConfigPlugins = plugins:
-    map (
-      plug:
-        if (isString plug)
-        then pluginBuilders.${plug} or (noBuildPlug {pname = plug;})
-        else plug
-    ) (filter (f: f != null) plugins);
-
-  # built (or "normalized") plugins that are modified
-  builtStartPlugins = buildConfigPlugins vimOptions.startPlugins;
-  builtOptPlugins = map (package: package // {optional = true;}) (buildConfigPlugins vimOptions.optPlugins);
-
-  # additional Lua and Python3 packages, mapped to their respective functions
-  # to conform to the format mnw expects. end user should
-  # only ever need to pass a list of packages, which are modified
-  # here
-  extraLuaPackages = ps: map (x: ps.${x}) vimOptions.luaPackages;
-  extraPython3Packages = ps: map (x: ps.${x}) vimOptions.python3Packages;
-
-  # Wrap the user's desired (unwrapped) Neovim package with arguments that'll be used to
-  # generate a wrapped Neovim package.
-  neovim-wrapped = inputs.mnw.lib.wrap pkgs {
-    neovim = vimOptions.package;
-    plugins = builtStartPlugins ++ builtOptPlugins;
-    appName = "nvf";
-    extraBinPath = vimOptions.extraPackages;
-    initLua = vimOptions.builtLuaConfigRC;
-    luaFiles = vimOptions.extraLuaFiles;
-
-    inherit (vimOptions) viAlias vimAlias withRuby withNodeJs withPython3;
-    inherit extraLuaPackages extraPython3Packages;
-  };
-
-  dummyInit = pkgs.writeText "nvf-init.lua" vimOptions.builtLuaConfigRC;
-  # Additional helper scripts for printing and displaying nvf configuration
-  # in your commandline.
-  printConfig = pkgs.writers.writeDashBin "nvf-print-config" "cat ${dummyInit}";
-  printConfigPath = pkgs.writers.writeDashBin "nvf-print-config-path" "echo -n ${dummyInit}";
 in {
   inherit (module) options config;
   inherit (module._module.args) pkgs;
 
   # Expose wrapped neovim-package for userspace
   # or module consumption.
-  neovim = pkgs.symlinkJoin {
+  neovim = module.config.vim.build.finalPackage;
-    name = "nvf-with-helpers";
-    paths = [neovim-wrapped printConfig printConfigPath];
-    postBuild = "echo Helpers added";
-
-    # Allow evaluating vimOptions, i.e., config.vim from the packages' passthru
-    # attribute. For example, packages.x86_64-linux.neovim.passthru.neovimConfig
-    # will return the configuration in full.
-    passthru.neovimConfig = vimOptions;
-
-    meta =
-      neovim-wrapped.meta
-      // {
-        description = "Wrapped Neovim package with helper scripts to print the config (path)";
-      };
-  };
 }

modules/modules.nix

@@ -48,6 +48,7 @@
     # The neovim wrapper, used to build a wrapped neovim package
     # using the configuration passed in `neovim` and `plugins` modules.
     wrapper = map (p: ./wrapper + "/${p}") [
+      "build"
       "environment"
       "rc"
       "warnings"

modules/wrapper/build/config.nix

@@ -0,0 +1,111 @@
+{
+  inputs,
+  lib,
+  config,
+  pkgs,
+  ...
+}
+: let
+  inherit (pkgs) vimPlugins;
+  inherit (lib.strings) isString;
+  inherit (lib.lists) filter map;
+
+  # alias to the internal configuration
+  vimOptions = config.vim;
+
+  noBuildPlug = {pname, ...} @ attrs: let
+    src = inputs."plugin-${attrs.pname}";
+  in
+    {
+      version = src.shortRev or src.shortDirtyRev or "dirty";
+      outPath = src;
+      passthru.vimPlugin = false;
+    }
+    // attrs;
+
+  # build a vim plugin with the given name and arguments
+  # if the plugin is nvim-treesitter, warn the user to use buildTreesitterPlug
+  # instead
+  buildPlug = attrs: let
+    src = inputs."plugin-${attrs.pname}";
+  in
+    pkgs.vimUtils.buildVimPlugin (
+      {
+        version = src.shortRev or src.shortDirtyRev or "dirty";
+        inherit src;
+      }
+      // attrs
+    );
+
+  buildTreesitterPlug = grammars: vimPlugins.nvim-treesitter.withPlugins (_: grammars);
+
+  pluginBuilders = {
+    nvim-treesitter = buildTreesitterPlug vimOptions.treesitter.grammars;
+    flutter-tools-patched = buildPlug {
+      pname = "flutter-tools";
+      patches = [../patches/flutter-tools.patch];
+    };
+  };
+
+  buildConfigPlugins = plugins:
+    map (
+      plug:
+        if (isString plug)
+        then pluginBuilders.${plug} or (noBuildPlug {pname = plug;})
+        else plug
+    ) (filter (f: f != null) plugins);
+
+  # built (or "normalized") plugins that are modified
+  builtStartPlugins = buildConfigPlugins vimOptions.startPlugins;
+  builtOptPlugins = map (package: package // {optional = true;}) (buildConfigPlugins vimOptions.optPlugins);
+
+  # additional Lua and Python3 packages, mapped to their respective functions
+  # to conform to the format mnw expects. end user should
+  # only ever need to pass a list of packages, which are modified
+  # here
+  extraLuaPackages = ps: map (x: ps.${x}) vimOptions.luaPackages;
+  extraPython3Packages = ps: map (x: ps.${x}) vimOptions.python3Packages;
+
+  # Wrap the user's desired (unwrapped) Neovim package with arguments that'll be used to
+  # generate a wrapped Neovim package.
+  neovim-wrapped = inputs.mnw.lib.wrap pkgs {
+    neovim = vimOptions.package;
+    plugins = builtStartPlugins ++ builtOptPlugins;
+    appName = "nvf";
+    extraBinPath = vimOptions.extraPackages;
+    initLua = vimOptions.builtLuaConfigRC;
+    luaFiles = vimOptions.extraLuaFiles;
+
+    inherit (vimOptions) viAlias vimAlias withRuby withNodeJs withPython3;
+    inherit extraLuaPackages extraPython3Packages;
+  };
+
+  dummyInit = pkgs.writeText "nvf-init.lua" vimOptions.builtLuaConfigRC;
+  # Additional helper scripts for printing and displaying nvf configuration
+  # in your commandline.
+  printConfig = pkgs.writers.writeDashBin "nvf-print-config" "cat ${dummyInit}";
+  printConfigPath = pkgs.writers.writeDashBin "nvf-print-config-path" "echo -n ${dummyInit}";
+
+  # Expose wrapped neovim-package for userspace
+  # or module consumption.
+  neovim = pkgs.symlinkJoin {
+    name = "nvf-with-helpers";
+    paths = [neovim-wrapped printConfig printConfigPath];
+    postBuild = "echo Helpers added";
+
+    # Allow evaluating vimOptions, i.e., config.vim from the packages' passthru
+    # attribute. For example, packages.x86_64-linux.neovim.passthru.neovimConfig
+    # will return the configuration in full.
+    passthru.neovimConfig = vimOptions;
+
+    meta =
+      neovim-wrapped.meta
+      // {
+        description = "Wrapped Neovim package with helper scripts to print the config (path)";
+      };
+  };
+in {
+  config.vim.build = {
+    finalPackage = neovim;
+  };
+}

modules/wrapper/build/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./options.nix
+    ./config.nix
+  ];
+}

modules/wrapper/build/options.nix

@@ -0,0 +1,12 @@
+{lib, ...}: let
+  inherit (lib.types) package;
+  inherit (lib.options) mkOption;
+in {
+  options.vim.build = {
+    finalPackage = mkOption {
+      type = package;
+      readOnly = true;
+      description = "final output package";
+    };
+  };
+}