mirror of
https://github.com/NotAShelf/neovim-flake.git
synced 2024-11-08 12:35:59 +01:00
f9789432f9
* modules: switch to gerg's neovim-wrapper * modules: use initViml instead of writing the file * treewide: make the entire generated config lua based * docs: remove mentions of configRC * plugins/treesitter: remove vim.cmd hack * treewide: move resolveDag to lib * modules/wrapper(rc): fix typo * treewide: migrate to pluginRC for correct DAG order The "new" DAG order is as follows: - (luaConfigPre) - globalsScript - basic - theme - pluginConfigs - extraPluginConfigs - mappings - (luaConfigPost) * plugins/theme: fix theme DAG place * plugins/theme: fix fixed theme DAG place * modules/wrapper(rc): add removed option module for configRC * docs: add dag-entries chapter, add release note entry * fix: formatting CI * languages/nix: add missing `local` * docs: fix page link * docs: add mention of breaking changes at the start of the release notes * plugins/neo-tree: convert to pluginRC * modules/wrapper(rc): add back entryAnywhere * modules/wrapper(rc): expose pluginRC * apply raf patch --------- Co-authored-by: NotAShelf <raf@notashelf.dev>
70 lines
2 KiB
Nix
70 lines
2 KiB
Nix
{
|
|
config,
|
|
pkgs,
|
|
lib,
|
|
...
|
|
}: let
|
|
inherit (lib.options) mkEnableOption mkOption;
|
|
inherit (lib.modules) mkIf mkMerge;
|
|
inherit (lib.meta) getExe;
|
|
inherit (lib.lists) isList;
|
|
inherit (lib.strings) optionalString;
|
|
inherit (lib.types) either listOf package str;
|
|
inherit (lib.nvim.types) mkGrammarOption;
|
|
inherit (lib.nvim.lua) expToLua;
|
|
inherit (lib.nvim.dag) entryBefore;
|
|
|
|
cfg = config.vim.languages.lua;
|
|
in {
|
|
options.vim.languages.lua = {
|
|
enable = mkEnableOption "Lua language support";
|
|
treesitter = {
|
|
enable = mkEnableOption "Lua Treesitter support" // {default = config.vim.languages.enableTreesitter;};
|
|
package = mkGrammarOption pkgs "lua";
|
|
};
|
|
|
|
lsp = {
|
|
enable = mkEnableOption "Lua LSP support via LuaLS" // {default = config.vim.languages.enableLSP;};
|
|
|
|
package = mkOption {
|
|
description = "LuaLS package, or the command to run as a list of strings";
|
|
type = either package (listOf str);
|
|
default = pkgs.lua-language-server;
|
|
};
|
|
|
|
neodev.enable = mkEnableOption "neodev.nvim integration, useful for neovim plugin developers";
|
|
};
|
|
};
|
|
|
|
config = mkMerge [
|
|
(mkIf cfg.treesitter.enable {
|
|
vim.treesitter.enable = true;
|
|
vim.treesitter.grammars = [cfg.treesitter.package];
|
|
})
|
|
|
|
(mkIf cfg.enable (mkMerge [
|
|
(mkIf cfg.lsp.enable {
|
|
vim.lsp.lspconfig.enable = true;
|
|
vim.lsp.lspconfig.sources.lua-lsp = ''
|
|
lspconfig.lua_ls.setup {
|
|
capabilities = capabilities;
|
|
on_attach = default_on_attach;
|
|
${optionalString cfg.lsp.neodev.enable "before_init = require('neodev.lsp').before_init;"}
|
|
cmd = ${
|
|
if isList cfg.lsp.package
|
|
then expToLua cfg.lsp.package
|
|
else ''{"${getExe cfg.lsp.package}"}''
|
|
};
|
|
}
|
|
'';
|
|
})
|
|
|
|
(mkIf cfg.lsp.neodev.enable {
|
|
vim.startPlugins = ["neodev-nvim"];
|
|
vim.pluginRC.neodev = entryBefore ["lua-lsp"] ''
|
|
require("neodev").setup({})
|
|
'';
|
|
})
|
|
]))
|
|
];
|
|
}
|