mirror of
https://github.com/NotAShelf/neovim-flake.git
synced 2024-12-24 20:29:49 +01:00
7dbd1cd8d1
* modules/completion: rewrite
* treewide: remove vsnip, add luasnip
* nvim-cmp: add default sorting
* nvim-cmp: load after luasnip
* lib: fix docs for mergelessListOf
* docs: add changelog entires for rewrite
* deprecations: add rewrite deprecations
* nvim-cmp: clarify in format description
* docs: fix option reference in release notes
* treewide: remove reduant `// {default = false;}`s
* luasnip: add missing `{option}` for option reference
* deprecations: add entry for vsnip
* nvim-autopairs: use multiline string
* nvim-dap: use outer attribute
76 lines
2.8 KiB
Nix
76 lines
2.8 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
...
|
|
}: let
|
|
inherit (lib.strings) optionalString;
|
|
inherit (lib.modules) mkIf mkMerge;
|
|
inherit (lib.attrsets) mapAttrs;
|
|
inherit (lib.nvim.binds) addDescriptionsToMappings mkSetLuaBinding;
|
|
inherit (lib.nvim.dag) entryAnywhere entryAfter;
|
|
|
|
cfg = config.vim.debugger.nvim-dap;
|
|
self = import ./nvim-dap.nix {inherit lib;};
|
|
mappingDefinitions = self.options.vim.debugger.nvim-dap.mappings;
|
|
mappings = addDescriptionsToMappings cfg.mappings mappingDefinitions;
|
|
in {
|
|
config = mkMerge [
|
|
(mkIf cfg.enable {
|
|
vim = {
|
|
startPlugins = ["nvim-dap"];
|
|
|
|
pluginRC =
|
|
{
|
|
# TODO customizable keymaps
|
|
nvim-dap = entryAnywhere ''
|
|
local dap = require("dap")
|
|
vim.fn.sign_define("DapBreakpoint", { text = "🛑", texthl = "ErrorMsg", linehl = "", numhl = "" })
|
|
'';
|
|
}
|
|
// mapAttrs (_: v: (entryAfter ["nvim-dap"] v)) cfg.sources;
|
|
|
|
maps.normal = mkMerge [
|
|
(mkSetLuaBinding mappings.continue "require('dap').continue")
|
|
(mkSetLuaBinding mappings.restart "require('dap').restart")
|
|
(mkSetLuaBinding mappings.terminate "require('dap').terminate")
|
|
(mkSetLuaBinding mappings.runLast "require('dap').run_last")
|
|
|
|
(mkSetLuaBinding mappings.toggleRepl "require('dap').repl.toggle")
|
|
(mkSetLuaBinding mappings.hover "require('dap.ui.widgets').hover")
|
|
(mkSetLuaBinding mappings.toggleBreakpoint "require('dap').toggle_breakpoint")
|
|
|
|
(mkSetLuaBinding mappings.runToCursor "require('dap').run_to_cursor")
|
|
(mkSetLuaBinding mappings.stepInto "require('dap').step_into")
|
|
(mkSetLuaBinding mappings.stepOut "require('dap').step_out")
|
|
(mkSetLuaBinding mappings.stepOver "require('dap').step_over")
|
|
(mkSetLuaBinding mappings.stepBack "require('dap').step_back")
|
|
|
|
(mkSetLuaBinding mappings.goUp "require('dap').up")
|
|
(mkSetLuaBinding mappings.goDown "require('dap').down")
|
|
];
|
|
};
|
|
})
|
|
(mkIf (cfg.enable && cfg.ui.enable) {
|
|
vim = {
|
|
startPlugins = ["nvim-dap-ui" "nvim-nio"];
|
|
|
|
pluginRC.nvim-dap-ui = entryAfter ["nvim-dap"] (''
|
|
local dapui = require("dapui")
|
|
dapui.setup()
|
|
''
|
|
+ optionalString cfg.ui.autoStart ''
|
|
dap.listeners.after.event_initialized["dapui_config"] = function()
|
|
dapui.open()
|
|
end
|
|
dap.listeners.before.event_terminated["dapui_config"] = function()
|
|
dapui.close()
|
|
end
|
|
dap.listeners.before.event_exited["dapui_config"] = function()
|
|
dapui.close()
|
|
end
|
|
'');
|
|
maps.normal = mkSetLuaBinding mappings.toggleDapUI "require('dapui').toggle";
|
|
};
|
|
})
|
|
];
|
|
}
|